Изучение простых чисел ведется с глубокой древности, как учеными, так и служителями различных культов. Одним из первых проблему выявления простых чисел поставил древнегреческий ученый Эратосфен, позднее значительных результатов удалось добиться и другим исследователям, среди которых выдающимися считаются работы П. Ферма, Л. Эйлера, К. Гаусса, А. Лежандра, П. Чебышева и ряда других учёных.

Простые числа являются ключом к разрешению многих математических проблем и появляются в разных областях математики и ее приложениях. Криптография, имитационное моделирование, тестирование материнских плат персональных компьютеров – вот современный перечень практического применения простых чисел. Поэтому простые числа интересуют не только математиков, но и некоторые коммерческие организации, а также военных (разведку и контрразведку), ввиду их особого применения в области защиты информации [1].

О важности вопроса изучения простых чисел говорят и следующие факты:

1) за поиск больших простых чисел назначены крупные денежные премии;

2) некоторые из простых чисел являются запрещенными (законы об авторском праве запрещают их хранить и распространять).

Существуют открытые проекты поиска простых чисел-рекордсменов, в которых каждый может принять участие [2-4].

В данной работе используются средства известной системы компьютерной математики Maple для исследования числовых последовательностей, которые могут содержать простые числа. Предлагаются инструменты исследования в виде Maple-процедур, позволяющих наглядно представить состав и структуру таких числовых последовательностей.

Дальнейшее изложение материала ведётся с вставкой фрагментов диалога с компьютером в среде рабочего листа Maple. Начало ячеек ввода помечается угловой скобкой вида “>”, содержимое этих ячеек – команды Maple, окрашено в красный цвет. В среде Maple легко получить справку по поводу действия каждой команды; для этого достаточно выделить её и нажать клавишу [F1] на клавиатуре. Ячейка ввода, законченная символом “точка с запятой (;)”, при исполнении (клавиша [Enter]) возвращает ячейку вывода – результат вычислений, содержимое которого по умолчанию окрашено в синий цвет. Некоторые команды в ячейке ввода порождают графическое изображение. Возможности Maple в области математической графики очень богаты. Отчасти этим и объясняется предпочтение авторов, отданное данному математическому пакету.

1. Натуральные числа: простые и составные

Напомним, что положительные числа, используемые для счета, называют натуральными. Последовательность натуральных чисел является бесконечной. Рассмотрим часть этой последовательности.

> restart:
> N := {k $ k = 1..30};

N:={1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24, 25, 26, 27, 28, 29, 30}

Один из способов разделения всего множества натуральных чисел на непересекающиеся подмножества следующий: простые числа, составные числа и единица.

Простые числа – это те, которые делятся без остатка только на 1 и самих себя, составные числа – те, которые могут быть представлены через произведение простых сомножителей.

Рассмотрим множество целых чисел от 2 до 30.

> Z := { seq(k, k = 2..30) };

Z:={2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24, 25, 26, 27, 28, 29, 30}

Выберем простые числа из этого множества.

> P := select( isprime, Z );

P:={2, 3, 5, 7, 11, 13, 17, 19, 23, 29}

Ни одно из них не разлагается на множители.

Теперь исключим простые числа из исходного множества. Это составные числа.

> C := remove( isprime, Z);

C:={4, 6, 8, 9, 10, 12, 14, 15, 16, 18, 20, 21, 22, 24, 25, 26, 27, 28, 30}

Каждое из полученных чисел раскладывается на множители.

> for k from 1 to nops(C) do C[k] = ifactor(C[k]): od;

4 = (2)^2

6 = (2)*3)

8 = (2)^3

9 = (3)^2

10 = (2)*(5)

12 = (2)^2*(3)

14 = (2)*(7)

15 = (3)*(5)

16 = (2)^4

18 = (2)*(3)^2

20 = (2)^2*(5)

21 = (3)*(7)

22 = (2)*(11)

24 = (2)^3*(3)

25 = (5)^2

26 = (2)*(13)

27 = (3)^3

28 = (2)^2*(7)

30 = (2)*(3)*(5)

Согласно «Основной теореме арифметики», впервые сформулированной и доказанной К. Гауссом в 1801 г. [5], такое разложение единственно. И это одна из причин, по которой математики не считают 1 простым числом. Ведь единицу можно добавлять в качестве сомножителя в любом количестве, и, тогда, о единственности разложения сказать затруднительно.

2. Простые числа на числовой прямой, решето Эратосфена

На первый взгляд расположение простых чисел в натуральном ряду кажется беспорядочным. Однако представим процесс нахождения простых чисел графически, воспользовавшись одним из древнейших методов нахождения простых чисел, называемым “Решето Эратосфена”.

Начать можно с изображения N натуральных чисел на числовой прямой. Затем произвести последовательные исключения (вычеркивания) всех чисел кратных простым. То есть вначале мы вычеркиваем все числа, кратные 2, затем все числа кратные 3, 5 и т.д. Вычеркивание будем производить при помощи синусоид, с периодом, кратным рассматриваемому числу.

Согласно правилу использования метода, вычеркивания производятся до числа, не превышающего квадрата наибольшего из простых делителей. Причина здесь в том, что для любого составного числа X наименьший целый делитель, кроме 1, расположен в пределах

Вот соответствующая Maple-процедура:

> with(plottools): with(plots):
nl:=proc(N)
local i,q,m,a,b,s,sn,c:
for i to N do
if isprime(i) then
  q[i]:=disk([i,0], 0.5, color=red):
 else
  q[i]:=disk([i,0], 0.5, color=yellow):
 end if:
 m[i]:=textplot([i,0,i]):
end do:
a:=seq(q[i],i=1..N):
b:=seq(m[i],i=1..N):
m:=isqrt(N):
s:=1:
for i to m while s<m do
 s:=ithprime(i):
 sn[i]:=plot(s*sin(x*Pi/s),x=s..N,y=-m..m,color=COLOR(RGB,i/s,i/m,s/m))
end do:
c:=seq(sn[k],k=1..i-1):
display(a,b,c,axes=none);
end proc:

Вычеркнем, например, все составные числа среди целых в промежутке от 0 до 50.

> nl(50);

Красным цветом выделены простые числа. Для удобства вычеркивающим синусоидам назначены различные цвета и амплитуды.

Обобщая можно предложить следующий способ вычеркивания всех составных чисел, начиная с некоторого целого v>p, где p – заданное простое число и заканчивая .

1. Вычисляем произведение периодических функций вида

где i пробегает значения всех простых чисел не превышающих р.

2. Строим полученную синусоиду на числовой оси.

> ss:=proc(v)
local p,k,h,t,P:
if isprime(v) then
p:=v:h:=p:
else
p:=prevprime(v):h:=p:
end if:
while h>2 do
t:=prevprime(h):
p:=p,t:
h:=t:
end do;
P:=1:
for k to nops([p]) do
P:=P*sin(x*Pi/p[k])
end do:
plot(P,x=p[1]+0.5..p[1]^2,tickmarks = [[seq(i, i = 1 .. p[1]^2)],[]]);
end proc:

Пусть p=7, тогда . Выполненная процедура ss(7) возвращает график с вычеркнутыми составными числами в промежутке от 7 до 49.

> ss(7);

Заметим, что на графике легко различить простые числа, отличающиеся между собой на 2, 4 и на 6 единиц. Такие разницы будут присутствовать и в дальнейшем.

3. Сравнимые по модулю и взаимно простые числа

Как простые, так и составные числа подчиняются ещё одному важному правилу: для данного целого отличного от нуля числа b, всякое целое число а единственным образом представимо в виде

а = bq + r , где   0≤ r < | b |.                                          (1)

При этом число q называется неполным частным, а число r – остатком от деления а на b . Получим подобное представление для нашего множества простых чисел при делении каждого из них на 2.

> b:=2:
> for k from 1 to nops(P) do P[k] = b*cat(`*`)*cat(floor(P[k]/b))+cat(irem(P[k],b)): od;

2 = 2*1+0

3 = 2*1+1

5 = 2*2+1

7 = 2*3+1

11 = 2*5+1

13 = 2*6+1

17 = 2*8+1

19 = 2*9+1

23 = 2*11+1

29 = 2*14+1

Рассматривая последний результат, вспомним ещё одно определение: говорят, что целые числа a и b равноостаточны или сравнимы по модулю натурального числа m > 1, если a и b имеют одинаковые остатки от деления на m. В нашем случае видно, что все простые числа (кроме двойки) сравнимы по модулю 2, т.к. имеют остаток от деления на двойку, равный 1. Но, таковы также и все нечётные числа. Поэтому все простые числа, кроме 2, – нечётные.

Числа могут быть также взаимно просты. В этом случае их наибольший общий делитель равен единице. Например, взаимно простыми с числом 2 являются все нечётные числа.

> t:=2: sp:=NULL:
for i to nops(N) do
if igcd(N[i],t)=1 then sp:=sp,N[i]; fi:
od:

sp;

1, 3, 5, 7, 9, 11, 13, 15, 17, 19, 21, 23, 25, 27, 29

В том числе, опять же, все простые, кроме числа 2.

Предложим вычислительный инструмент – процедуру для представления любого множества чисел в виде (1)

> sm:=proc(b,s)
local k:
for k from 1 to nops(s) do print(s[k] = b*cat(`*`)*cat(floor(s[k]/b))+cat(irem(s[k],b))):  od;
end proc:

Например, представим каждое число из множества

> sa:={seq(k, k = 592..600)};

sa:={592, 593, 594, 595, 596, 597, 598, 599, 600}

в виде разложения (1) при делении на 23:

> sm(23,sa);

592 = 23*25+17

593 = 23*25+18

594 = 23*25+19

595 = 23*25+20

596 = 23*25+21

597 = 23*25+22

598 = 23*26+0

599 = 23*26+1

600 = 23*26+2

Следующая процедура выделяет из исходного множества числа, взаимно простые с предложенным числом.

> sc:=proc(t,ss)
local sp,i:
sp:=NULL:
for i to nops(ss) do
if igcd(ss[i],t)=1 then sp:=sp,ss[i]; fi:
od:
sp;
end proc:

Например, выделим из множества целых чисел Z взаимно простые с числом 6:

> sc(6,Z);

5, 7, 11, 13, 17, 19, 23, 25, 29

Представим каждое из этих чисел в виде разложения (1):

> sm(6,{%});

5 = 6*0+5

7 = 6*1+1

11 = 6*1+5

13 = 6*2+1

17 = 6*2+5

19 = 6*3+1

23 = 6*3+5

25 = 6*4+1

29 = 6*4+5

Проверим с помощью функции Эйлера, что количество чисел меньших 6 и взаимно простых с 6 равно двум:

> numtheory[phi](6);

2

Это числа 1 и 5.

Как видим, все целые числа взаимно простые с числом 6 входят в одну из двух арифметических прогрессий

> seq(6*n+5,n=0..10);# или seq(6*n-1,n=1..11), что то же самое

5, 11, 17, 23, 29, 35, 41, 47, 53, 59, 65

или

> seq(6*n+1,n=1..10);

7, 13, 19, 25, 31, 37, 43, 49, 55, 61

Эти прогрессии включают все числа, не делящиеся на 2 или 3, и поэтому каждое простое число, большее 3 входит в одну из этих прогрессий. В онлайн-энциклопедии целочисленных последовательностей [6] указано несколько способов получения обобщённой последовательности для обоих прогрессий, в том числе вычислением по формуле:

> seq((6*n+(-1)^n-3)/2, n=2..22);

5, 7, 11, 13, 17, 19, 23, 25, 29, 31, 35, 37, 41, 43, 47, 49, 53, 55, 59, 61, 65, 67

4. Геометрическое представление простых чисел по заданному модулю

Использование сравнений по модулю допускает наглядное представление целых чисел с использованием не числовой прямой, как обычно, а числовой окружности [7]. Окружность при этом делится на b частей. Всякое целое число при делении на b даёт в качестве остатка одно из чисел 0, 1, 2, …, b-1; эти числа расставляются по окружности на равных расстояниях. Каждое число сравнимо с одним из этих чисел по модулю b и, следовательно, представляется соответствующей точкой. Два числа сравнимы, если изображаются одной и той же точкой. Мы представим их как лежащие на одном луче, начало которого располагается в центре окружности.

Ниже предлагается процедура cr, выстраивающая целые числа, сравнимые по модулю с b (второй аргумент) на лучах, проходящих через соответствующую точку окружности. Первым аргументом процедуры является количество изображаемых на луче чисел.

> restart:

> cr:=proc(t,b)
local i,pn,p,c1,w,n,j, ch:
n:=0:
for i to t do
for j to b do
n:=n+1:
pn[n]:= [i,evalf(j*2*Pi/b),n-1];
ch[n]:=pn[n][3]
end do
end do:
w:={seq(pn[k],k=1..t*b)}:
for i from 1 to nops(w) do
if isprime(ch[i]) then
p[i]:=plots[textplot]([w [i]], coords=polar,color=red):
else
p[i]:=plots[textplot]([w[i]], coords=polar,color=black):
end if:
end do:
c1:=seq(p[k],k=1..t*b):
plots[display](c1,axes=none);
end proc:

Например, изобразим на окружности по 10 чисел, сравнимых по модулю с числом 6. Красным цветом на графике помечены простые числа.

> cr(10,6);

Мы видим, что все простые числа, кроме 2 и 3, попали на два луча, на которых располагаются всё те же последовательности чисел, описываемые формулами 6n-1 и 6n+1.

В теории чисел используется понятие “классы вычетов по модулю b“. Каждый такой класс содержит бесконечное количество сравнимых между собой целых чисел, объединенных одним соотношением (1), то есть при делении на b дающих одинаковый остаток r. В нашем примере каждый числовой луч соответствует классу вычетов по модулю 6.

5. Бесконечность последовательности простых чисел

Простые числа могут быть очень большими. Например, число, найденное в 1971 году [2] имеет вид:

> x:=2^19937-1:
`В этом числе`*cat(length(%))*`знака`;

В этом числе 6002 знака

Это одно из чисел Мерсенна, которые вычисляются по формуле , где n – натуральное число, и давно удерживают лидерство как самые большие известные простые числа. Устроим ему проверку (компьютеру потребуется некоторое время, возможно, пара минут).

> isprime(x);

true

Проверка показывает, что х – простое число.

В настоящее время наибольшее простое число (найдено в 2008 году) содержит 12 978 189 десятичных знаков [3]. Оно вычислено с помощью формулы для чисел Мерсенна как .

Если считать, что на одной странице книги обычного формата помещается около 2000 символов, то можно вычислить сколько страниц займёт это число в книге:

> `Это число в книге займет` * cat(irem(12978189,2000)) *`страниц`;

 Это число в книге займёт 189 страниц

Однако чем дальше от начала натурального ряда, тем все реже встречаются простые числа. Известная гипотеза, высказанная Лежандром, утверждает, что количество простых чисел, не превосходящих данное натуральное число n, – можно приближенно оценить следующей функцией:

> p:=n->n/(ln(n)-1.08366);

Скорость ее возрастания постепенно (весьма незначительно) уменьшается:

> pp:=diff(p(n),n);

Для больших чисел график производной показывает уменьшение скорости роста функции Лежандра на десятые и сотые доли единицы при изменении n на порядок

> plot(pp(n),n=0..10^10,0..0.06);

Согласно гипотезе Лежандра количество простых чисел, не превосходящих 10000, будет примерно равно:

> p(10000.);

1230.514742

На самом деле: вот простые числа слева и справа от 10000:

> prevprime(10000);

9973

> nextprime(10000);

10007

Путем подбора устанавливаем

> ithprime(1229);

9973

То есть число 9973 – это 1229-е простое число в натуральном ряду. Таким образом, гипотеза Лежандра в данном диапазоне дает чуть завышенную, но достаточно точную оценку.

Действительно ли последовательность простых чисел бесконечна? Ответ на этот вопрос утвердительный. Доказательство бесконечности множества простых чисел следует из единственности разложения (1) всякого целого числа и присутствует уже у Евклида в его знаменитых “Началах”.  Суть доказательства в следующем. Пусть p₁, p₂, …, p_n – все известные нам простые числа. Перемножим их и прибавим единицу, получим число P = p₁× p₂×  …× p_n+1, которое больше любого известного простого числа. При этом Р не делится без остатка ни на одно из простых p₁, p₂, …, p_n. Значит либо само это число Р является простым, либо делится на другое простое число, не включённое в известный набор. Например, нам известно только 8 простых чисел:

> restart: A:=seq(ithprime(k),k=1..8);

A:=2,3,5,7,11,13,17,19

 Прибавим единицу к их произведению:

> a:=product(A[j],j=1..6)+1;
isprime(a);

a:=30031

false

Получили составное число, разлагаемое на простые множители:

> ifactor(a);

(59)(509)

Оба эти простые числа не были нам известны по условию задачи.

Литература

1. Найдена секретная экспонента для 12720 публичных ключей RSA. http://www.xakep.ru/post/58288/

2. Great Internet Mersenne Prime Search. GIMPS. Finding World Record Primes Since 1996. http://mersenne.org/

3. Еще раз о поиске простых чисел. http://habrahabr.ru/blogs/algorithm/114490/

4. Prime Grid. http://www.primegrid.com/forum_thread.php?id=3874

5. Дэвенпорт Г. Высшая арифметика: Введение в теорию чисел. – М.: УРСС, 2010. – 176 с.

6. The On-Line Encyclopedia of Integer Sequences. http://oeis.org

7. Курант Р., Роббинс Г. Что такое математика? – М.: МЦНМО, 2004. – 568 с.

В работе [1]  были предложены ряд инструментов – Maple-процедур для исследования последовательности простых чисел. Данная статья продолжает развитие темы. Принятые соглашения остаются прежними: красный шрифт используется для записи команд Maple, синий шрифт и графики – результат выполнения команд.

В математике простых чисел особое место занимает знаменитая гипотеза, сформулированная выдающимся немецким математиком Георгом Фридрихом Бернардом Риманом в 1859 году, и называемая «Гипотезой Римана» [2]. Согласно этой гипотезе, характер распределения простых чисел может существенно отличаться от предполагаемого в настоящее время. Дело в том, что математикам до сих пор не удавалось точно зафиксировать наличие какой-либо системы в характере распределения простых чисел. Считается, например, что в окрестности целого числа х среднее расстояние между последовательными простыми числами пропорционально логарифму х, так что имеет мест аcимтотическая формула

p ~ k ln(k),                                                                                                                 (1)

где p – величина простого числа, k – его номер по порядку. Знак ~ в выражении (1) означает, что отношение p/(k ln(k)) с ростом k стремится к 1.

Изобразим на одной диаграмме график функции p(k) с экспериментально подобранным поправочным коэффициентом 1,16k и точечный истинных значений первых 150 простых чисел (по оси абсцисс откладывается номер простого числа, а по оси ординат – его значение).

> restart:
> N:=150:
p:=seq(ithprime(i),i=1..N):#где i – номер простого числа
a:=plot([seq([n,p[n]],n=1..N)],style=point,symbol=circle,color=blue):
b:=plot([seq([k,1.16*k*ln(k)],k=1..N)]):
plots[display]([a,b]);

Асимптотическая формула даёт хорошее приближение. И оно было бы ещё лучше, если бы в последовательности простых не встречались так называемые простые числа-близнецы – парные простые числа,  разность между которыми равна 2, то есть 11 и 13, 29 и 31, 59 и 61. Эти числа более всего нарушают общую картину.

Ещё одно асимптотическое равенство впервые доказанное Карлом Фридрихом Гауссом записывается как

π(x)~x/ln(x), x→∞,

и называется в настоящее время законом распределения простых чисел. Функция π(x) в этом законе выражает количество простых чисел, меньших или равных x.

1  Проблема простых чисел-близнецов

Замечено, что все пары простых-близнецов, кроме (3,5), имеют вид 6k-1 и 6k+1, где k – натуральное число.

Построим процедуру blz(N), которая возвращает пары чисел близнецов, начиная с пары (5,7) и заканчивая парой чисел, не превышающих (N-2,N), где N – параметр процедуры. На точечном графике изображаются только эти пары чисел (по оси абсцисс откладываются номера пар). В основе процедуры лежит цикл с шагом i=6.

> restart:
blz:=proc(N)
local i,a,b,t1,t2:
t1:=NULL:t2:=NULL:
for i from 7 to N by 6 do
if isprime(i) and isprime(i-2) then lprint(i-2,i): t1:=t1,i-2:t2:=t2,i: end if:
end do:
t1:=[t1]:t2:=[t2]:
a:=plot([seq([n,t1[n]],n=1..nops(t1))],style=point,symbol=circle,color=red):
b:=plot([seq([k,t2[k]],k=1..nops(t2))],style=point,symbol=circle,color=blue):
plots[display](a,b):
end proc:

Выделим близнецов из первых 150 натуральных чисел

> blz(200);

5, 7
11, 13
17, 19
29, 31
41, 43
59, 61
71, 73
101, 103
107, 109
137, 139
149, 151
179, 181
191, 193
197, 199

Из результата видно, что простые близнецы могут образовать кластеры (скопления), например 101, 103, 107, 109. У математиков давно существовало подозрение, что такие скопления существуют и в области очень больших простых чисел, однако ни доказать, ни опровергнуть это утверждение до сих пор не удавалось. Если такие кластеры будут найдены, стойкость криптографических ключей, используемых в настоящее время, может оказаться под очень большим вопросом.

Математическое сообщество в полной мере оценило важность задачи — гипотеза Римана была признана одной из 7 важнейших научных проблем тысячелетия. Институт математики Clay в США предложил $1 млн. за ее доказательство либо опровержение. И периодически средства массовой информации, математики-профессионалы и любители сообщают о некоторых “значительных” прорывах в данной области.

2  Распределение простых чисел близнецов

Следующая процедура blz_1(N) подсчитывает число пар “близнецов”, не превышающих числа N и строит график интегральной функции распределения числа пар близнецов, не превышающих N (цикл с шагом 6).

> restart:
blz_1:=proc(N)
global M:
local m,i:
printf(“%s             %s”,i,m); print():
printf(“====================”); print():
m:=0:M:=NULL:
for i from 7 to N by 6 do
if isprime(i) and isprime(i-2) then m:=m+1:
printf(“%g             %gn”,i,m):
end if:
M:=M,[i,m];
end do:
lprint(“для множества чисел не превышающих”, N):
lprint(“число пар близнецов”=m):
plot([M])
end proc:

Выведем, например, значения и график функции для аргумента, не превышающего N =900:

> blz_1(900);

i             m
====================
7             1
13             2
19             3
31             4
43             5
61             6
73             7
103             8
109             9
139             10
151             11
181             12
193             13
199             14
229             15
241             16
271             17
283             18
313             19
349             20
421             21
433             22
463             23
523             24
571             25
601             26
619             27
643             28
661             29
811             30
823             31
829             32
859             33
883             34

“для множества чисел не превышающих”, 900

“число пар близнецов” = 34

Наблюдаем, что число пар близнецов растёт (правда, неравномерно).

Предполагается, что пар близнецов бесконечно много, но это не доказано. По гипотезе Харди-Литтлвуда [2], количество  пар простых-близнецов, не превосходящих x, асимптотически приближается к

где

- константа простых-близнецов. Произведение вычисляется по всем простым числам, начиная с тройки (это второе простое число, поэтому последовательность простых чисел, формируемая ниже, создается для для счётчика i начиная с числа 2).

Так, для 10000 множителей константа  С2 равна

> n:=10000:
s:=seq(ithprime(i),i=2..n):
C2:=1:
for p in [s] do C2:=C2*(1-1/((p-1)^2)) end do:
evalf(C2);

0.6601623198 

Оценим значение функции π2(x)

> pi2:=x->2*C2*int(1/(ln(t)^2),t = 2 .. x);

При x = 900, значение π2(x) равно

> ceil(pi2(900.));

 43

Истинное значение функции нами было получено выше, оно равно 34. Чтобы график функции лучше совпадал с графиком истинного распределения простых близнецов на отдельных участках можно вновь ввести поправочные коэффициенты, т.к. как соотношение для π2(x) приближённое. Например, для области определения [200, 900] примем поправочный коэффициент 0,78.

> a:=plot([M],color=blue):
b:=plot(0.78*pi2(x),x=200..900):
plots[display](a,b);

Получено визуально удовлетворительное приближение.

3  Теорема Бруна

В 1919 году норвежский математик Вигго Брун исследовал ряд

где в круглых скобках раcположены суммы чисел, обратных простым близнецам [3].

Предложим процедуру для изучения свойств суммы этого ряда

> restart:
brun:=proc(n)
local s, B2, i, a:
s:=seq(ithprime(k),k=1..n+1):
B2:=NULL:
print(B2);
for i to n do
if s[i]-s[i+1]=-2 then B2:=B2,1/s[i]+1/s[i+1]:end if:
end do:
B2:=[B2]:
print(B2);
a:=plot([seq([t,sum(B2[k1],k1=1..t)],t=1..nops(B2))],style=point,symbol=circle,color=red):
sum(B2[u],u=1..nops(B2));
print(`Сумма ряда`,evalf(%));
plots[display](a):
end proc:

Возьмём 100 членов ряда

> brun(100);

Аналогичный результат без перечисления значения сумм:

> brun(1000);

Мы наблюдаем, что график изменения суммы ряда сначала идёт резко вверх, а затем скорость роста значений существенно замедляется. В. Брун доказал, что этот ряд сходится.

Значение B2=1,902160583104 называется константой Бруна для простых-близнецов, при этом

Это означает, что если простых близнецов и бесконечно много, то они все же расположены в натуральном ряду довольно редко.

4  Классы простых-близнецов

Попробуем выделить отдельные классы простых-близнецов. Пусть в этом нам поможет следующая таблица, состоящая из 30 столбцов, предложенная в работе [4].

Соответствующая процедура, создающая такую таблицу (позиции составных чисел в ней отмечены прочерками) приводится ниже.

> Fm:=proc(Q::integer)
global M,P:
local i,j,k,w,t,m,mn,a,b:
M:=array(1..Q,1..30);
k:=0:
for i to Q do
for j to 30 do
if i=1 and j<16 then M[i,j]:=`-`
else
   k:=k+1:
   if isprime(k) then
     M[i,j]:=k:
   else
   M[i,j]:=`-`
   end if:
end if:
end do:
end do:
w:=[seq(2*i*Pi/30,i=1..30)];
for t to Q do
  m:=[seq(M[t,j],j=1..30)];
 mn[t]:=seq([m[i],w[i]],i=1..30);
end do:
P:=[seq(mn[ik],ik=1..Q)]:
print(evalm(M));
end proc:

Начало натурального ряда находится в середине первой строки таблицы. Рассмотрим, к примеру, таблицу в 30 строк.

> Fm(30);

В полученной таблице можно отчётливо выделить три непересекающихся подмножества простых чисел – близнецов. Это пары чисел, которые заканчиваются на 7 и 9, 9 и 1, 1 и 3.

Известная теорема утверждает, что по модулю 30 все пары близнецов, кроме первых двух, имеют вид (11, 13), (17, 19) или (29, 31);  именно эти числа стоят во главе соответствующих столбцов.

Напомним, что два натуральных числа a и b, разность которых кратна натуральному числу m (эти числа имеют одинаковые остатки при делении на m), называются сравнимыми по модулю m. Например, к одному подмножеству отнесём пары близнецов (1451, 1453) и (1481, 1483), так как для них имеем

> 1481 mod 30 = 1451 mod 30;

11=11

> 1483 mod 30 = 1453 mod 30;

 13=13

Рассмотрим распределения простых-близнецов каждого из трёх подмножеств. Для этого создадим процедуру, в которой действует цикл с шагом 30, внутри которого с шагом 12 проверяются на простоту пары “близнецов”)

> restart:
tc:=proc(N)
local q,Q,r,R,s,S,a,b,c,i:
q:=0:Q:=NULL:r:=0:R:=NULL:s:=0:S:=NULL:
for i from 19 to N by 30 do
if isprime(i) and isprime(i-2) then q:=q+1:
Q:=Q,[i,q]:
end if:
if isprime(i+12) and isprime(i+12-2) then r:=r+1:
R:=R,[i+12,r]:
end if:
if isprime(i+24) and isprime(i+24-2) then s:=s+1:
S:=S,[i+24,s]:
end if:
end do:
a:=plot([Q],color=red,style=point):#на 7 и 9
b:=plot([R],color=blue,style=point):#на 9 и 1
c:=plot([S],color=green,style=point):#на 1 и 3
plots[display](a,b,c);
end proc:

Процедура возвращает графики распределения простых-близнецов каждого из трёх подмножеств: красный цвет – близнецы, равные по модулю 17 или 19, синий – 29 или 31, зелёный – 11 или 13. Например, среди первых 10000 натуральных чисел

> tc(10000);

Судя по графику эти три распределения близки между собой. Получим график в пределах первых 50 миллионов натуральных чисел (внимание: расчёт по программе требует времени).

> tc(50000000);

Из последнего графика видно, что в пределах эти 50 миллионов находится примерно по 80 тысяч пар близнецов каждого класса. Если бесконечен ряд простых близнецов, то, по-видимому, бесконечны и данные три последовательности.

Литература

1. Смирнов В.В., Спиридонов Ф.Ф. Компьютерная математика в исследовании простых чисел. // Современные научные исследования и инновации. – Февраль, 2013 [Электронный ресурс]. URL: https://web.snauka.ru/issues/2013/02/20410

2. Диамонд Г. “Элементарные методы в изучении распределения простых чисел”, // УМН, 45:2(272) (1990), 79–114 c.

3. Трост Э. Простые числа – М.: ГИФМЛ, 1959. – 135 с.

4. Omar E. Pol. Sobre el patron de los numeros primos. Determinacion geometrica de los numeros primos y perfectos. – [Электронный ресурс]. URL:  http://www.polprimos.com/

В работах [1] и [2] представлены разработки Maple-процедур, позволяющих изучать распределение простых в пространстве одного и двух измерений. В настоящей статье тема будет продолжена. Речь пойдёт о двух наиболее обсуждаемых и отчасти родственных геометрических представлениях целочисленных последовательностей: скатерти Улама и спирали Сакса. Хотя обозреваемые геометрические структуры являются всего лишь формой, значимость подобных исследований состоит в том, что они должны способствовать поиску наиболее «простого», понятного и конструктивного распределения простых чисел.

1. Скатерть Улама

Один из наиболее компактных способов иллюстрации размещения простых чисел на плоскости был обнаружен в 1963 году Станиславом Уламом [3].

Улам размещал натуральные числа, начиная с некоторого данного, по спирали, вначале на бумажном листе в клетку, затем на экране компьютера по соответствующей программе. При этом положение простых чисел отмечалось особо. В результате получалось изображение, называемое теперь скатертью Улама.

Следующая процедура Ulam(s,z,ch) возвращает изображение скатерти Улама для s витков спирали.

> restart:
> with(plottools): with(plots):
> Ulam:=proc(s,z,ch)
local tt,t1,x,y,n,i,j,p,c,a,b:
tt:=NULL:t1:=NULL:
tt:=tt,[0,0]: t1:=[0,0,ch]:
x:=0: y:=0: n:=1:
for i from 1 to s*2 do
 if i mod 2 = 1 then
  for j to i do
   n:=n+1:x:=x+1: tt:=tt,[x,y]: t1:=t1,[x,y,n+ch-1]:
  end do:
  for j to i do
   n:=n+1: y:=y+1: tt:=tt,[x,y]:t1:=t1,[x,y,n+ch-1]:
  end do:
 else
  for j to i do
   n:=n+1:x:=x-1: tt:=tt,[x,y]: t1:=t1,[x,y,n+ch-1]:
  end do:
  for j to i do
   n:=n+1:y:=y-1: tt:=tt,[x,y]:t1:=t1,[x,y,n+ch-1]:
  end do:
 end if:
end do:
for i to n do
if isprime(i+ch-1) then
 p[i]:=disk(tt[i], 0.5, color=red)
else
 p[i]:=disk(tt[i], 0.5, color=yellow)
end if:
end do:
c:=seq(p[i],i=1..n):
a:=plot([tt],color=blue):
if z=1 then
b:=textplot([t1]):
else b:=textplot([[0,0,ch],[x,y,n]]):
end if:
plots[display](a,b,c,axes=none);
end proc:

При значении второго параметра процедуры z=1 на диаграмму выводятся числа, иначе – лишь изображающие их цветные точки: красные – соответствуют простым числам, жёлтые – составным числам. Третий параметр ch указывает на число, которое будет находиться в центре спирали.

Рассмотрим, к примеру, шесть витков спирали Улама, начиная с числа 17.

> Ulam(6,1,17);

Мы ясно видим, что в скатерти Улама примечательно то, что простые числа стремятся выстроиться по диагоналям, образуя довольно длинные цепочки. Обнаружено, что эти цепочки являются вычисляемыми значениями некоторых квадратичных многочленов [4], например,  (см. рисунок выше) или  (как в следующем случае) при x=0,1,2,3,4 и т.д.

> Ulam(7,1,41);

Процедура Ulam выполняется немного быстрее, если задать параметр z=0; в этом случае на график выводится только единица и последнее число рассматриваемой последовательности.

Следующая спираль имеет 20 витков, начинается с единицы, прочие числа (кроме последнего) в ней не отображены, но по цвету точек мы можем судить о расположении на скатерти простых чисел

> Ulam(20,0,1);

2. Спираль Сакса

В 1994 году Роберт Сакс, основываясь на скатерти Улама, разработал свой вариант спирали [5]. В ней целые неотрицательные числа выводятся не на квадратной, а на архимедовой спирали, и расположены они так, что квадрат целого числа воспроизводится один раз в каждом витке спирали (в спирали Улама мы встречаем два квадрата целого числа на витке).

Ниже предлагается Maple-процедура RS для воспроизведения спирали Сакса.

> restart:with(plottools):with(plots):
> rs:=proc(N,q)
local w,b,i,p,c:
if q=1 then w:=seq([i,sqrt(i)*2*Pi,i],i=0..N) else w:=seq([i,sqrt(i)*2*Pi],i=0..N) end if:
b:=plot((x/2/Pi)^2,x=0..sqrt(N)*2*Pi, coords=polar,axes=none,scaling=constrained,color=blue):
for i from 1 to N do
 if isprime(i-1) then
  if q=1 then p[i]:=textplot([w [i]], coords=polar,color=red):
  else p[i]:=plot([w [i]], style=point, symbol=circle,symbolsize=10, coords=polar,color=red):end if:
 else
  if q=1 then p[i]:=textplot([w[i]], coords=polar,color=black):
  else p[i]:=plot([w [i]],style=point, coords=polar,color=black,symbolsize=6):end if:
 end if:
end do:
c:=seq(p[i],i=1..N):
plots[display](b,c);
end proc:

Эта процедура имеет следующие входные параметры: N (указывает сколько чисел изображать на спирали) и q (при q=1 на диаграмму выводятся числа, в противном случае – точки, соответствующие их положению). Простым числам на диаграмме соответствует красный цвет.

Изобразим, к примеру, на спирали Сакса шестьдесят пять целых чисел и добавим на диаграмму пару линий S и Р, играющих в данном геометрическом представлении особую роль.

> S:=seq([i^2,sqrt(i^2)*2*Pi],i=0..8):
P:=seq([i^2+i,sqrt(i^2+i)*2*Pi],i=0..8):
c:=plot([P],coords=polar,symbolsize=15,scaling=constrained,color=black):
b:=plot([S],coords=polar,symbolsize=15,scaling=constrained,color=black):
a:=rs(65,1):
display(a,b,c);

На графике видно, что все квадраты целых чисел (1, 4, 9, 16, 25, …) выстроились справа в один ряд, образуя как бы «нулевой луч», выходящий из полюса, обозначенного числом 1.

Этот луч также можно именовать «осью квадратов», так как числа на ней представляют собой произведения (1×1, 2×2, 3×3 и т.д.); в нашем обозначении это S-линия.

Последовательность чисел на линии S  задается формулой  при x=1..∞ .

В общем случае числовые ряды образуют кривые линии, берущие начало в центре спирали.

Вторая характерная линия, назовем ее P-линия – это кривая, на которой размещены числа 2, 6, 12, 20, 30, 42. Эти числа представляют собой произведения соседних пар чисел натурального ряда 1×2, 2×3, 3×4, 4×5, 5×6 и т.д.

Соответствующая последовательность  или    при x=1..∞ .

Таким образом, числа, расположенные на S-линии, могут быть факторизованы с разницей между множителями, составляющей 0 (ноль), т.е. 1=1×1, 4=2×2, 9=3×3 и т.д., а числа на P-линии могут быть разложены на множители с разницей между ними 1.

Имея эти две характерные линии легко разобраться в сути многих других линий, обозреваемых на круглой скатерти Сакса. Так, рядом с S-линией находится линия S-1, все числа которой на единицу меньше (на соответствующем витке), чем те, которые расположились на линии S. Поэтому числа кривой S-1 могут быть представлены множителями с разницей в 2: 3=1×3, 8=2×4, 15=3×5, 24=4×6 и т.д. Формула последовательности   при x=2.. ∞.

Найдём на рисунке следующую рассматриваемую кривую, которая содержит числа  4=1×4, 10=2×5, 18=3×6 и т. д.; здесь разница множителей 3. По понятным причинам, эту кривую удобно называть Р-2. Формула соответствующей последовательности   при x=2..∞ .

Отметим теперь, что число 4 появилось на двух кривых: на одной как произведение 2×2, на другой как 1×4.

Мы можем и дальше продолжать отмечать кривые с увеличивающейся разницей между множителями.

И будем получать кривые S-1, S-2, S-3, …, и S+1, S+2, S+3, …, а также P-1, P-2, P-3, … и P+1, P+2, P+3, …

Сакс называет эти кривые кривыми произведений, потому что числа, расположенные на них состоят из произведений с фиксированной разницей между множителями.

Каждое целое число окажется, по крайней мере, на одной из этих кривых. Составные числа будут принадлежать более чем одной из этих кривых, а простые числа – только одной.

Пользуясь спиралью Сакса, можно исследовать структуру многих производящих последовательности простых чисел полиномов [6]. Например, ниже изображено положение на спирали Сакса членов последовательности , изучавшейся Эйлером и дающей много простых чисел.

> eu:=seq([i^2+i+41,sqrt(i^2+i+41)*2*Pi],i=0..50):
c:=plot([eu],coords=polar,symbolsize=15,scaling=constrained,color=black):
a:=rs(2500,0):
display(a,c);

Список использованных источников

1. Смирнов В.В., Спиридонов Ф.Ф. Компьютерная математика в исследовании простых чисел. // Современные научные исследования и инновации. – Февраль, 2013 [Электронный ресурс]. URL: https://web.snauka.ru/issues/2013/02/20410

2. Смирнов В.В., Спиридонов Ф.Ф. Maple-инструменты исследования простых чисел-близнецов. // Современные научные исследования и инновации. – Февраль, 2013 [Электронный ресурс]. URL: https://web.snauka.ru/issues/2013/02/22270

3. A visual analysis of prime number distribution [Электронный ресурс]. URL: http://www.ulamspiral.com/

4. Матиясевич Ю.В. Формулы для простых чисел. // Квант.- 1975. – № 5. – С. 5 – 13.

5. Sacks spiral [Электронный ресурс]. URL: http://www.numberspiral.com

6. Prime-Generating Polynomial [Электронный ресурс]. URL: http://mathworld.wolfram.com/Prime-GeneratingPolynomial.html

Простые числа были известны давно, многие учёные занимались ими, пытались найти некий порядок в их распределении среди остальных натуральных чисел. Использовались при этом три основные группы методов исследования:

• аналитические – заключающиеся в построении и выводе формул;
• алгоритмические – основанные на привлечении какого-либо алгоритма, позволяющего выделить множество простых из множества натуральных чисел;
• геометрические, графические или, как теперь говорят, визуальные методы, позволяющие каким-то образом предъявить изображение простые числа среди натуральных чисел.

Многие годы никому не удавалось достичь положительных результатов с помощью первого метода. Но греческий учёный Эратосфен придумал уникальный метод второго типа, который затем был назван «Решетом Эратосфена». Он состоит в последовательном вычёркивании составных чисел среди натуральных. При этом постепенно становятся видны простые числа, одно за одним. Недостатком метода является значительный объём вычислений, возникающий при умножении и делении очень больших чисел. Этот метод используется до сих пор, в том числе в различных вычислительных модификациях с помощью вычислительной техники, ускоряющих его работу [1,2].

Во времена Эратосфена графический или визуальный метод при решении этой задачи почти не использовался. Обычно анализировалось распределение чисел вдоль прямой линии, на которой числа в виде точек помечались разными цветами. Надо отметить, что в те времена и в последующие графический метод не принёс существенных положительных результатов.

Одним из первых аналитический метод применил Л.Эйлер. Он представил распределение простых чисел в отдельных подмножествах из их множества квадратичной зависимостью вида: x²+x+q, где q – целое число большее или равное нулю. Этот результат был получен и хорошо работал для чисел x<100. Надо отметить, что чем дальше продвигаться вдоль числовой оси, тем реже и беспорядочнее расположены простые числа. В дальнейшем метод Эйлера практически не получил развития, если не считать нахождение чисел q, таких, что формула последовательности Эйлера даёт наибольшее количество простых чисел.

В начале и в середине XX-го века учёные обратились к третьему, геометрическому методу. Предпринимались многочисленные попытки  расположить простые числа на плоскости в виде спиралей (наиболее известные из которых носят имена спирали Улама и спирали Сакса). Это был новый подход к этой задаче – рассматривать и располагать числа на плоскости определённым образом. Применение его надо признать успешным, т.к. он позволил буквально разглядеть некоторый порядок в расположении простых чисел между собой [3]. Тем не менее, большего увидеть и изучить не удавалось, т.е. метод оказался тоже ограниченным для отдельных подмножеств простых чисел из их множества. Вместе с тем, частичный порядок в распределении простых чисел стал виден и понятен, что немаловажно.

К концу XX-го века было введено понятие фракталов – объектов, размерность которых не является целым числом. В то же время, фракталы обладают свойством самоподобия, т.е. отдельные их элементы по структуре совпадают с самим фракталом. Были сделаны попытки применить фракталы к задаче о распределении простых чисел, однако, и они не принесли ощутимых результатов. Тем не менее, эти попытки продолжаются до сих пор.

Исследователи с переменным успехом занимались также рассмотрением матриц, содержащих простые и составные числа. Рассматривались прямоугольные матрицы самых разных размеров. Некоторые интересные результаты по расположению простых чисел в матрицах были получены, но, к сожалению, продолжения этих работ не было. По нашему мнению в данном направлении можно получить новые результаты, что и является целью настоящей работы.

Основная часть

Рассмотрим множество натуральных чисел. Известно, что все простые числа, за исключением 2 и 3 располагаются слева и справа от чисел кратных числу 6. В этой связи числа 2 и 3 можно считать особыми и исключить их из рассмотрения при дальнейшем анализе. Их особенность заключается в том, что это единственная пара смежных простых чисел. Поэтому в дальнейшем, по причине указанной выше, обратимся к матрицам с числом столбцов кратным числу 6. В этих матрицах будем располагать числа из множества натуральных чисел, исключив по приведённым выше причинам из этого множества числа 1, 2, 3 и все чётные числа. В указанном множестве останутся лишь простые и нечётные составные числа, представляющие собой произведения простых чисел. Первым простым числом будет 5.

Однако вначале отступим от выбранной схемы и обратимся всё-таки к матрице, число столбцов которой равно 4, ограничившись двумя десятками её строк.  Эта матрица показана на рисунке 1-а с числами, записанными в ней по порядку. Сплошными линиями разных цветов соединены простые числа и составные числа, кратные числу 5. Из рисунка хорошо видно, что линия, соединяющая составные числа, идёт сверху вниз, образуя изгибы, имеющие впадины слева и справа. Аналогичную картину мы наблюдаем, соединяя составные числа, кратные 7 и 11. Иными словами, в положении составных чисел наблюдается некоторая упорядоченность. Для простых же чисел, соединённых ломаной линией, даже при тщательном рассмотрении никакой упорядоченности не наблюдается. Кроме того, что немаловажно, нетрудно видеть, что последний столбец матрицы не содержит никаких чисел, т.е. пуст.

Перейдём к матрице с числом столбцов равных числу 6. Она показана на рисунке 1-б с размещёнными в ней числами. Здесь последний столбец также пуст, т.е. не содержит чисел. На рисунке показаны три ломаные линии. Одна соединяет числа кратные числу 5, другая – числа кратные числу 7, третья – числа кратные числу 11. Простые числа хорошо видны, но не показана соответствующая ломаная линия, которая могла бы соединять их последовательно. Она не показана для того чтобы не затемнять рисунок. Из рисунка видно, что упорядоченность последовательностей чисел по сравнению с рис.1а возросла. По сравнению с рис.1а заметны более выраженные пики или впадины на ломаных линиях. Кроме того, расстояния между пиками или впадинами стали существенно меньше, чем на рисунке 1-а.

а)

б)

Рисунок 1 – Матрицы с четырьмя (а) и шестью столбцами (б)

Перейдём к матрице с числом столбцов равных числу 12. Она показана на рисунке 2 с размещёнными в ней числами. Здесь последний столбец также пуст, т.е. не содержит чисел.

Рисунок 2 – Матрица 12 столбцов

Ломаные линии имеют как бы “пилообразный” вид. При этом шаг между вершинами (или впадинами) возрастает с ростом начального числа: 5, 7, 11. Все начальные числа являются простыми и последовательными во множестве простых чисел.

Таким образом, при увеличении числа столбцов матрицы с 4 до 6 и 12 упорядоченность рассматриваемых подмножеств чисел из множества натуральных возросла.

Перейдём к матрице с 18 столбцами, которая показана на рисунке 3. Хорошо видно, что упомянутая выше упорядоченность нарушилась. По сравнению с рисунками 1 и 2 регулярность в расположении вершин и впадин на всех линиях исчезла. Теперь трудно как-то однозначно описать поведение каждой из ломаных линий.

Рисунок 3 – Матрица 18 столбцов

Двигаясь дальше, рассмотрим матрицу с 24 столбцами, изображённую на рисунке 4. Видно, что какую-либо упорядоченность ломаных линий определить затруднительно.

Рисунок 4 – Матрица 24 столбца

Таким образом, отмеченная тенденция уменьшения упорядоченности в распределении простых и составных чисел существенно возрастает при переходе от матрицы с 12 столбцами к матрице с числом столбцов 18, 24 и более.

Выводы

Рассматривая эти результаты в совокупности можно сделать следующие выводы и указать направления возможных дальнейших исследований.

Во-первых, упорядоченность распределения составных чисел, начинающихся с простых чисел 5, 7 и 11, постепенно возрастает при возрастании числа столбцов в рассматриваемых матриц с 6 до 12. Последняя наиболее упорядоченная. Это же относится, что легко показать, и к последовательностям составных чисел, начинающихся с чисел 13, 17, 19 и т.д. Кроме того, рассмотренные распределения в некотором смысле эквивалентны. Имеется в виду следующее. Достаточно поделить каждое число из соответствующего подмножества чисел на на­чальное число 5, 7, 11 и т.д. Тогда получатся последовательности чисел начинающиеся с числа 1. Подробное рассмотрение этой эквивалентности пока не входило в задачи авторов.

Во-вторых. С ростом числа столбцов в матрицах больше 12 упорядоченность рассматриваемых распределений уменьшается и сменяется разупорядоченностью. Иными словами, происходит как бы разрушение порядка.

В третьих, можно рассмотреть степень упорядоченности в последовательности простых чисел.

В заключение можно отметить интересную особенность всех рассмотренных матриц, а именно – отсутствие любых чисел в последнем столбце. В этом все рассмотренные матрицы подобны между собой. Учитывая эту особенность рассмотренных матриц, можно осуществить следующую операцию: свернуть каждую из матриц в цилиндрическую поверхность и, например, приклеить последний из столбцов под первым. Тогда рассмотренные распределения перейдут на поверхности цилиндров разных радиусов – в зависимости от числа столбцов соответствующих матриц. При этом распределения простых и составных чисел переходят в 3-мерное пространство. Такой результат, насколько известно авторам, ранее никем получен не был.